Implement a qmake-based build for Subsurface

This is working for me, but requires a bit more testing. To build,
run:
  qmake [options]

Where options might be:
  V=1               disable "silent" build
  LIBDCDEVEL=1      use side-by-side libdivecomputer
  INCLUDEPATH+=xxx  add -Ixxx (e.g., INCLUDEPATH+=/usr/local/marble/include)
  LIBS+=xxx         add xxx to the linker flags (e.g. LIBS+=-L/usr/local/marble/lib)
  or any other qmake option, including debug and release options

If your distribution is already using qtchooser in place of qmake, you
may need to pass an extra option to qmake to select the a
cross-build. For example:

  qmake -qt=i686-w64-mingw32-qt4

If your distribution is not yet using qtchooser, then you need to file
a bug report requesting it and you need to run the full path to qmake.

Note:
 - there are some ### left in the buildsystem

Signed-off-by: Thiago Macieira <thiago@macieira.org>

1 files changed, 16 insertions, 0 deletions

diff --git a/subsurface-gen-version.pri b/subsurface-gen-version.pri
new file mode 100644
index 000000000..a94a65adb
--- /dev/null
+++ b/subsurface-gen-version.pri
@@ -0,0 +1,16 @@
+# Generate the version.h file
+VERSION_FILE = version.h
+exists(.git/HEAD): {
+    GIT_HEAD = .git/HEAD
+    VERSION_SCRIPT = $$PWD/scripts/get-version
+    version_h.depends = $$VERSION_SCRIPT
+    version_h.commands = echo \\$${LITERAL_HASH}define VERSION_STRING \\\"`$$VERSION_SCRIPT linux`\\\" > ${QMAKE_FILE_OUT}
+    version_h.input = GIT_HEAD
+    version_h.output = $$VERSION_FILE
+    version_h.variable_out = GENERATED_FILES
+    version_h.CONFIG = ignore_no_exist
+    QMAKE_EXTRA_COMPILERS += version_h
+} else {
+    # This is probably a package
+    system(echo \\$${LITERAL_HASH}define VERSION_STRING \\\"$$VERSION\\\" > $$VERSION_FILE)
+}