From 3f070eadd1bf0f04f6b25dd362f3d6bbeb323f7c Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Tue, 17 Feb 2015 19:16:20 +0200
Subject: XSLT to import MacDive logs

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 303 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 303 insertions(+)
 create mode 100644 xslt/DiveLog.xslt

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
new file mode 100644
index 000000000..579e177da
--- /dev/null
+++ b/xslt/DiveLog.xslt
@@ -0,0 +1,303 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+  <xsl:strip-space elements="*"/>
+  <xsl:output method="xml" indent="yes"/>
+
+  <xsl:template match="/">
+    <divelog program='subsurface-import' version='2'>
+      <settings>
+          <divecomputerid deviceid="ffffffff">
+            <xsl:attribute name="model">
+              <xsl:value-of select="logbook/@program"/>
+            </xsl:attribute>
+            <xsl:attribute name="serial">
+              <xsl:value-of select="logbook/@serialNumber"/>
+            </xsl:attribute>
+          </divecomputerid>
+      </settings>
+      <dives>
+        <xsl:apply-templates select="/logbook"/>
+      </dives>
+    </divelog>
+  </xsl:template>
+
+  <xsl:template match="dive">
+    <xsl:variable name="units" select="/logbook/prefs/@units"/>
+
+    <dive>
+      <xsl:attribute name="number">
+        <xsl:value-of select="@Number"/>
+      </xsl:attribute>
+
+      <xsl:attribute name="date">
+        <xsl:value-of select="concat(substring-after(substring-after(substring-before(@DateTime, ' '), '/'), '/'), '-', substring-before(@DateTime, '/'), '-', substring-before(substring-after(@DateTime, '/'), '/'))"/>
+      </xsl:attribute>
+
+      <xsl:attribute name="duration">
+        <xsl:call-template name="timeConvert">
+          <xsl:with-param name="timeSec" select="@Duration"/>
+          <xsl:with-param name="units" select="$units"/>
+        </xsl:call-template>
+      </xsl:attribute>
+
+      <xsl:variable name="delta">
+        <xsl:value-of select="@SampleInterval"/>
+      </xsl:variable>
+
+      <location>
+        <xsl:value-of select="@Location"/>
+        <xsl:if test="@Location != '' and @Site != ''">
+          <xsl:text> / </xsl:text>
+        </xsl:if>
+        <xsl:value-of select="@Site"/>
+      </location>
+
+      <notes>
+        <xsl:value-of select="notes"/>
+      </notes>
+
+      <cylinder>
+        <xsl:if test="@StartPSI &gt; 0">
+          <xsl:attribute name="start">
+            <xsl:call-template name="pressureConvert">
+              <xsl:with-param name="number" select="@StartPSI"/>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+        </xsl:if>
+        <xsl:if test="@EndPSI &gt; 0">
+          <xsl:attribute name="end">
+            <xsl:call-template name="pressureConvert">
+              <xsl:with-param name="number" select="@EndPSI"/>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+        </xsl:if>
+        <xsl:if test="@TankSize &gt; 0">
+          <xsl:attribute name="size">
+            <xsl:call-template name="sizeConvert">
+              <xsl:with-param name="singleSize" select="@TankSize"/>
+              <xsl:with-param name="double" select="'0'"/>
+              <xsl:with-param name="pressure" select="@WorkingPressure"/>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+        </xsl:if>
+        <xsl:if test="@WorkingPressure &gt; 0">
+          <xsl:attribute name="workpressure">
+            <xsl:call-template name="pressureConvert">
+              <xsl:with-param name="number" select="@WorkingPressure"/>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+        </xsl:if>
+        <xsl:if test="@Tank != ''">
+          <xsl:attribute name="description">
+            <xsl:value-of select="@Tank"/>
+          </xsl:attribute>
+        </xsl:if>
+        <xsl:if test="@NitroxEnrichment != '' and @NitroxEnrichment != 21">
+          <xsl:attribute name="o2">
+            <xsl:value-of select="concat(@NitroxEnrichment, '%')"/>
+          </xsl:attribute>
+        </xsl:if>
+      </cylinder>
+
+      <xsl:if test="@Weight != ''">
+        <weightsystem>
+          <xsl:attribute name="weight">
+            <xsl:call-template name="weightConvert">
+              <xsl:with-param name="weight" select="translate(@Weight, ',', '.')"/>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+          <xsl:attribute name="description">
+            <xsl:value-of select="'unknown'"/>
+          </xsl:attribute>
+        </weightsystem>
+      </xsl:if>
+
+      <buddy>
+        <xsl:value-of select="@DiveBuddy"/>
+      </buddy>
+
+      <divemaster>
+        <xsl:value-of select="@DiveMaster"/>
+      </divemaster>
+
+      <divecomputer deviceid="ffffffff">
+        <xsl:attribute name="model">
+          <xsl:value-of select="@Computer"/>
+        </xsl:attribute>
+
+      <depth>
+        <xsl:attribute name="max">
+          <xsl:call-template name="depthConvert">
+            <xsl:with-param name="depth">
+              <xsl:value-of select="@MaxDepth"/>
+            </xsl:with-param>
+            <xsl:with-param name="units" select="$units"/>
+          </xsl:call-template>
+        </xsl:attribute>
+        <xsl:attribute name="mean">
+          <xsl:call-template name="depthConvert">
+            <xsl:with-param name="depth">
+              <xsl:value-of select="@AverageDepth"/>
+            </xsl:with-param>
+            <xsl:with-param name="units" select="$units"/>
+          </xsl:call-template>
+        </xsl:attribute>
+      </depth>
+
+
+      <temperature>
+        <xsl:attribute name="air">
+          <xsl:call-template name="tempConvert">
+            <xsl:with-param name="temp" select="@AirTemp"/>
+            <xsl:with-param name="units" select="$units"/>
+          </xsl:call-template>
+        </xsl:attribute>
+
+        <xsl:attribute name="water">
+          <xsl:call-template name="tempConvert">
+            <xsl:with-param name="temp" select="@WaterTempMD"/>
+            <xsl:with-param name="units" select="$units"/>
+          </xsl:call-template>
+        </xsl:attribute>
+      </temperature>
+
+      <xsl:for-each select="profile">
+        <sample>
+          <xsl:attribute name="time">
+            <xsl:call-template name="timeConvert">
+              <xsl:with-param name="timeSec">
+                <xsl:value-of select="@sample * $delta"/>
+              </xsl:with-param>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+          <xsl:attribute name="depth">
+            <xsl:call-template name="depthConvert">
+              <xsl:with-param name="depth">
+                <xsl:value-of select="@depth"/>
+              </xsl:with-param>
+              <xsl:with-param name="units" select="$units"/>
+            </xsl:call-template>
+          </xsl:attribute>
+        </sample>
+      </xsl:for-each>
+      </divecomputer>
+
+    </dive>
+  </xsl:template>
+
+  <!-- convert pressure to bars -->
+  <xsl:template name="pressureConvert">
+    <xsl:param name="number"/>
+    <xsl:param name="units"/>
+
+    <xsl:choose>
+      <xsl:when test="$units != 'Metric'">
+        <xsl:value-of select="concat(format-number(($number div 14.5037738007), '#.##'), ' bar')"/>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:value-of select="concat($number, ' bar')"/>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  <!-- end convert pressure -->
+
+  <!-- convert cuft to litres -->
+  <xsl:template name="sizeConvert">
+    <xsl:param name="singleSize"/>
+    <xsl:param name="double"/>
+    <xsl:param name="pressure"/>
+    <xsl:param name="units"/>
+
+    <xsl:variable name="size">
+      <xsl:value-of select="format-number($singleSize + $singleSize * $double, '#.##')"/>
+    </xsl:variable>
+
+    <xsl:choose>
+      <xsl:when test="$units != 'Metric'">
+        <xsl:if test="$pressure != '0'">
+          <xsl:value-of select="concat(format-number((($size * 14.7 div $pressure) div 0.035315), '#.##'), ' l')"/>
+        </xsl:if>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:value-of select="concat($size, ' l')"/>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  <!-- end convert pressure -->
+
+  <!-- convert temperature from F to C -->
+  <xsl:template name="tempConvert">
+    <xsl:param name="temp"/>
+    <xsl:param name="units"/>
+
+    <xsl:choose>
+      <xsl:when test="$units != 'Metric'">
+        <xsl:if test="$temp != ''">
+          <xsl:value-of select="concat(format-number(($temp - 32) * 5 div 9, '0.0'), ' C')"/>
+        </xsl:if>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:if test="$temp != ''">
+          <xsl:value-of select="concat($temp, ' C')"/>
+        </xsl:if>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  <!-- end convert temperature -->
+
+  <!-- convert time in seconds to minutes:seconds -->
+  <xsl:template name="timeConvert">
+    <xsl:param name="timeSec"/>
+    <xsl:param name="units"/>
+
+    <xsl:if test="$timeSec != ''">
+      <xsl:value-of select="concat(floor(number($timeSec) div 60), ':',    format-number(floor(number($timeSec) mod 60), '00'), ' min')"/>
+    </xsl:if>
+  </xsl:template>
+  <!-- end convert time -->
+
+  <!-- convert depth to meters -->
+  <xsl:template name="depthConvert">
+    <xsl:param name="depth"/>
+    <xsl:param name="units"/>
+
+    <xsl:choose>
+      <xsl:when test="$units != 'Metric'">
+        <xsl:value-of select="concat(format-number(($depth * 0.3048), '#.##'), ' m')"/>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:value-of select="concat($depth, ' m')"/>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  <!-- end convert depth -->
+
+  <!-- convert weight to kg -->
+  <xsl:template name="weightConvert">
+    <xsl:param name="weight"/>
+    <xsl:param name="units"/>
+
+    <xsl:choose>
+      <xsl:when test="$weight &gt; 0">
+        <xsl:choose>
+          <xsl:when test="$units != 'Metric'">
+            <xsl:value-of select="concat(format-number(($weight * 0.453592), '#.##'), ' kg')"/>
+          </xsl:when>
+          <xsl:otherwise>
+            <xsl:value-of select="concat($weight, ' kg')"/>
+          </xsl:otherwise>
+        </xsl:choose>
+      </xsl:when>
+      <xsl:otherwise>
+        <xsl:value-of select="$weight"/>
+      </xsl:otherwise>
+    </xsl:choose>
+  </xsl:template>
+  <!-- end convert weight -->
+
+</xsl:stylesheet>
-- 
cgit v1.2.3-70-g09d2


From 4f26240b559893792d65ec57fc776285297cdd09 Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Tue, 17 Feb 2015 21:32:58 +0200
Subject: Add time to DiveLog import

I originally thought about converting the time as well, but my fingers
were too slow and memory too short to actually do that :D

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 4 ++++
 1 file changed, 4 insertions(+)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index 579e177da..66a3fd061 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -32,6 +32,10 @@
         <xsl:value-of select="concat(substring-after(substring-after(substring-before(@DateTime, ' '), '/'), '/'), '-', substring-before(@DateTime, '/'), '-', substring-before(substring-after(@DateTime, '/'), '/'))"/>
       </xsl:attribute>
 
+      <xsl:attribute name="time">
+        <xsl:value-of select="substring-after(@DateTime, ' ')"/>
+      </xsl:attribute>
+
       <xsl:attribute name="duration">
         <xsl:call-template name="timeConvert">
           <xsl:with-param name="timeSec" select="@Duration"/>
-- 
cgit v1.2.3-70-g09d2


From 371feac82f5d8e29bb74d55c3187bd2a38a5e5e1 Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Tue, 17 Feb 2015 21:32:59 +0200
Subject: Add visibility and weather to dive notes

This adds a bit more information to dive notes on DiveLog import.

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 5 +++++
 1 file changed, 5 insertions(+)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index 66a3fd061..b4bab8905 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -55,8 +55,13 @@
         <xsl:value-of select="@Site"/>
       </location>
 
+      <xsl:variable name="lf">
+        <xsl:text>
+</xsl:text>
+      </xsl:variable>
       <notes>
         <xsl:value-of select="notes"/>
+        <xsl:value-of select="concat($lf, 'Weather: ', @Weather, $lf, 'Visibility: ', @Visibility)"/>
       </notes>
 
       <cylinder>
-- 
cgit v1.2.3-70-g09d2


From f7365015ff250052ca7d26f4c655b774f3773960 Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Wed, 18 Feb 2015 19:55:29 +0200
Subject: Include Boat in DiveLog import

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 3 +++
 1 file changed, 3 insertions(+)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index b4bab8905..9855ae34e 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -62,6 +62,9 @@
       <notes>
         <xsl:value-of select="notes"/>
         <xsl:value-of select="concat($lf, 'Weather: ', @Weather, $lf, 'Visibility: ', @Visibility)"/>
+        <xsl:if test="@Boat != '' and @Boat != ' '">
+          <xsl:value-of select="concat($lf, 'Boat: ', @Boat)"/>
+        </xsl:if>
       </notes>
 
       <cylinder>
-- 
cgit v1.2.3-70-g09d2


From b87eb781920cd85534d295f75a3b61d382c088a5 Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Wed, 18 Feb 2015 19:55:30 +0200
Subject: Add serial number to DiveLog import

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 23 +++++++++++++++++++----
 1 file changed, 19 insertions(+), 4 deletions(-)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index 9855ae34e..818b50d49 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -2,17 +2,31 @@
   <xsl:strip-space elements="*"/>
   <xsl:output method="xml" indent="yes"/>
 
+  <xsl:key name="DC" match="dive" use="concat(@ComputerID, ':', @Computer)"/>
+
   <xsl:template match="/">
     <divelog program='subsurface-import' version='2'>
       <settings>
-          <divecomputerid deviceid="ffffffff">
+        <!-- Using the serial number as device ID for now. Once we have
+             a change to get some testing done, we can jump on using
+             extension that provides sha1 function.
+
++  xmlns:crypto="http://exslt.org/crypto"
++  extension-element-prefixes="crypto"
++        <divecomputerid deviceid="{substring(crypto:sha1(concat(@ComputerID, ':', @Computer)), 1, 8)}">
+
+-->
+
+        <xsl:for-each select="logbook/dive[generate-id() = generate-id(key('DC',concat(@ComputerID, ':', @Computer))[1])]">
+          <divecomputerid deviceid="{@ComputerID}">
             <xsl:attribute name="model">
-              <xsl:value-of select="logbook/@program"/>
+              <xsl:value-of select="@Computer"/>
             </xsl:attribute>
             <xsl:attribute name="serial">
-              <xsl:value-of select="logbook/@serialNumber"/>
+              <xsl:value-of select="@ComputerID"/>
             </xsl:attribute>
           </divecomputerid>
+        </xsl:for-each>
       </settings>
       <dives>
         <xsl:apply-templates select="/logbook"/>
@@ -136,7 +150,8 @@
         <xsl:value-of select="@DiveMaster"/>
       </divemaster>
 
-      <divecomputer deviceid="ffffffff">
+      <divecomputer deviceid="{@ComputerID}">
+
         <xsl:attribute name="model">
           <xsl:value-of select="@Computer"/>
         </xsl:attribute>
-- 
cgit v1.2.3-70-g09d2


From 541ec4fcac56aa13ea09bd8a4a30902d6f5109af Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Wed, 18 Feb 2015 19:55:31 +0200
Subject: Add some extra data for DiveLog import

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 10 ++++++++++
 1 file changed, 10 insertions(+)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index 818b50d49..7d21b10bd 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -156,6 +156,16 @@
           <xsl:value-of select="@Computer"/>
         </xsl:attribute>
 
+        <extradata key="Sample Interval" value="{@SampleInterval}"/>
+
+        <xsl:if test="@AltitudeMode != ''">
+          <extradata key="Altitude Mode" value="{@AltitudeMode}"/>
+        </xsl:if>
+
+        <xsl:if test="@PersonalMode != ''">
+          <extradata key="Personal Mode" value="{@PersonalMode}"/>
+        </xsl:if>
+
       <depth>
         <xsl:attribute name="max">
           <xsl:call-template name="depthConvert">
-- 
cgit v1.2.3-70-g09d2


From 554b652d25d9ce853c4f8f2044f80ab1b198fb1b Mon Sep 17 00:00:00 2001
From: Miika Turkia <miika.turkia@gmail.com>
Date: Wed, 18 Feb 2015 19:55:32 +0200
Subject: DiveLog import: Only include weight when available

Signed-off-by: Miika Turkia <miika.turkia@gmail.com>
Signed-off-by: Dirk Hohndel <dirk@hohndel.org>
---
 xslt/DiveLog.xslt | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

(limited to 'xslt')

diff --git a/xslt/DiveLog.xslt b/xslt/DiveLog.xslt
index 7d21b10bd..b94e28796 100644
--- a/xslt/DiveLog.xslt
+++ b/xslt/DiveLog.xslt
@@ -128,7 +128,7 @@
         </xsl:if>
       </cylinder>
 
-      <xsl:if test="@Weight != ''">
+      <xsl:if test="@Weight != '' and @Weight != '0.0'">
         <weightsystem>
           <xsl:attribute name="weight">
             <xsl:call-template name="weightConvert">
-- 
cgit v1.2.3-70-g09d2