blob: 87c5d91936913172aa1bb01aa5e6a23cb26587a9 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
include(subsurface-configure.pri)
QT = core gui network webkit svg
INCLUDEPATH += qt-ui $$PWD
mac: TARGET = Subsurface
else: TARGET = subsurface
VERSION = 3.1
HEADERS = \
color.h \
deco.h \
device.h \
display.h \
dive.h \
divelist.h \
file.h \
flag.h \
gettextfromc.h \
gettext.h \
helpers.h \
libdivecomputer.h \
planner.h \
pref.h \
profile.h \
qt-gui.h \
qthelper.h \
qt-ui/about.h \
qt-ui/completionmodels.h \
qt-ui/divecomputermanagementdialog.h \
qt-ui/divelistview.h \
qt-ui/diveplanner.h \
qt-ui/downloadfromdivecomputer.h \
qt-ui/globe.h \
qt-ui/graphicsview-common.h \
qt-ui/kmessagewidget.h \
qt-ui/maintab.h \
qt-ui/mainwindow.h \
qt-ui/modeldelegates.h \
qt-ui/models.h \
qt-ui/plotareascene.h \
qt-ui/preferences.h \
qt-ui/printdialog.h \
qt-ui/printlayout.h \
qt-ui/printoptions.h \
qt-ui/profilegraphics.h \
qt-ui/simplewidgets.h \
qt-ui/starwidget.h \
qt-ui/subsurfacewebservices.h \
qt-ui/tableview.h \
satellite.h \
sha1.h \
statistics.h \
subsurface-icon.h \
subsurfacestartup.h \
uemis.h \
webservice.h
SOURCES = \
deco.c \
device.c \
dive.c \
divelist.c \
equipment.c \
file.c \
gettextfromc.cpp \
libdivecomputer.c \
main.cpp \
parse-xml.c \
planner.c \
profile.c \
qt-gui.cpp \
qthelper.cpp \
qt-ui/about.cpp \
qt-ui/completionmodels.cpp \
qt-ui/divecomputermanagementdialog.cpp \
qt-ui/divelistview.cpp \
qt-ui/diveplanner.cpp \
qt-ui/downloadfromdivecomputer.cpp \
qt-ui/globe.cpp \
qt-ui/graphicsview-common.cpp \
qt-ui/kmessagewidget.cpp \
qt-ui/maintab.cpp \
qt-ui/mainwindow.cpp \
qt-ui/modeldelegates.cpp \
qt-ui/models.cpp \
qt-ui/plotareascene.cpp \
qt-ui/preferences.cpp \
qt-ui/printdialog.cpp \
qt-ui/printlayout.cpp \
qt-ui/printoptions.cpp \
qt-ui/profilegraphics.cpp \
qt-ui/simplewidgets.cpp \
qt-ui/starwidget.cpp \
qt-ui/subsurfacewebservices.cpp \
qt-ui/tableview.cpp \
save-xml.c \
sha1.c \
statistics.c \
subsurfacestartup.c \
time.c \
uemis.c \
uemis-downloader.c
linux*: SOURCES += linux.c
mac: SOURCES += macos.c
win32: SOURCES += windows.c
FORMS = \
qt-ui/about.ui \
qt-ui/divecomputermanagementdialog.ui \
qt-ui/diveplanner.ui \
qt-ui/downloadfromdivecomputer.ui \
qt-ui/maintab.ui \
qt-ui/mainwindow.ui \
qt-ui/preferences.ui \
qt-ui/printoptions.ui \
qt-ui/renumber.ui \
qt-ui/subsurfacewebservices.ui \
qt-ui/tableview.ui
RESOURCES = subsurface.qrc
TRANSLATIONS = \
subsurface_bg_BG.ts \
subsurface_ca_ES.ts \
subsurface_da_DK.ts \
subsurface_de_CH.ts \
subsurface_de_DE.ts \
subsurface_es_ES.ts \
subsurface_et_EE.ts \
subsurface_fi_FI.ts \
subsurface_fr_FR.ts \
subsurface_hr_HR.ts \
subsurface_it_IT.ts \
subsurface_nb_NO.ts \
subsurface_nl_NL.ts \
subsurface_pl_PL.ts \
subsurface_pt_BR.ts \
subsurface_pt_PT.ts \
subsurface_ru_RU.ts \
subsurface_sk_SK.ts \
subsurface_sv_SE.ts
doc.commands = $(CHK_DIR_EXISTS) Documentation || $(MKDIR) Documentation
doc.commands += $$escape_expand(\\n\\t)$(MAKE) -C $$PWD/Documentation OUT=$$OUT_PWD/Documentation doc
all.depends += doc
QMAKE_EXTRA_TARGETS += doc all
DESKTOP_FILE = subsurface.desktop
mac: ICON = packaging/macosx/Subsurface.icns
else: ICON = subsurface-icon.svg
MANPAGE = subsurface.1
XSLT_FILES = xslt
DOC_FILES = $$OUT_PWD/Documentation/user-manual.html Documentation/images
MARBLEDIR = marbledata/maps
DEPLOYMENT_PLUGIN += imageformats/qjpeg
# This information will go into the Windows .rc file and linked into the .exe
QMAKE_TARGET_COMPANY = subsurface team
QMAKE_TARGET_DESCRIPTION = subsurface dive log
QMAKE_TARGET_COPYRIGHT = Linus Torvalds, Dirk Hohndel and others
# And this is the Mac Info.plist file
# qmake automatically generates sed rules to replace:
# token qmake expansion
# @ICON@ $$ICON
# @TYPEINFO@ first 4 chars of $$QMAKE_PKGINFO_TYPEINFO
# @EXECUTABLE@ $$QMAKE_ORIG_TARGET
# @LIBRARY@ $$QMAKE_ORIG_TARGET
# @SHORT_VERSION@ $$VER_MAJ.$$VER_MIN
QMAKE_INFO_PLIST = packaging/macosx/Info.plist.in
OTHER_FILES += $$DESKTOPFILE $$ICON $$MANPAGE $$XSLT_FILES $$DOC_FILES $$MARBLEDIR \
$$QMAKE_INFO_PLIST
include(subsurface-gen-version.pri)
include(subsurface-install.pri)
|
