import mobilecomponents

This commit adds the .qml and qmldir files for the MobileComponents
import. It contains low-level things like units and theme, and mid-level
things like Heading, and high-level navigation in the form of an
ApplicationWindow and Drawers that hold menues and provide swipe
interactions between the pages.

These components are a more full version of the "light" plasma
components we have been using to make the UI scale well and appear more
consistent (coloring, spacing, alignment, etc.).

An interesting change is that Units and Theme are now singleton types,
which is more efficient. It does mean a few changes to our current API
usage:
- units becomes Units
- theme becomes Theme
- 2 properties move out of each (we can't subclass singleton types)

This change also means that we're using the vanilla upstream components,
so it's very easy to get improvements to these rather young components
in, and we don't have to do this work on our own.

The mobilecomponents consist of just a bunch of qml files which we can
deploy through the qrc file.

In the next commits, we will gradually make the current UI use these new
elements.

Signed-off-by: Sebastian Kügler <sebas@kde.org>

1 files changed, 93 insertions, 0 deletions

diff --git a/qt-mobile/qml/mobilecomponents/ContextDrawer.qml b/qt-mobile/qml/mobilecomponents/ContextDrawer.qml
new file mode 100644
index 000000000..2e2f95f7e
--- /dev/null
+++ b/qt-mobile/qml/mobilecomponents/ContextDrawer.qml
@@ -0,0 +1,93 @@
+/*
+ *   Copyright 2015 Marco Martin <mart@kde.org>
+ *
+ *   This program is free software; you can redistribute it and/or modify
+ *   it under the terms of the GNU Library General Public License as
+ *   published by the Free Software Foundation; either version 2, or
+ *   (at your option) any later version.
+ *
+ *   This program is distributed in the hope that it will be useful,
+ *   but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *   GNU Library General Public License for more details
+ *
+ *   You should have received a copy of the GNU Library General Public
+ *   License along with this program; if not, write to the
+ *   Free Software Foundation, Inc.,
+ *   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
+ */
+
+import QtQuick 2.1
+import QtQuick.Controls 1.0 as QtControls
+import org.kde.plasma.mobilecomponents 0.2
+
+OverlayDrawer {
+    id: root
+
+    property string title
+
+    //This can be any type of object that a ListView can accept as model. It expects items compatible with either QAction or QQC Action
+    property var actions
+    enabled: menu.count > 0
+    edge: Qt.RightEdge
+
+    contentItem: QtControls.ScrollView {
+        ListView {
+            id: menu
+            model: {
+                if (root.actions.length == 0) {
+                    return null;
+                } else {
+                    return root.actions[0].text !== undefined &&
+                        root.actions[0].trigger !== undefined ?
+                            root.actions :
+                            root.actions[0];
+                }
+            }
+            verticalLayoutDirection: ListView.BottomToTop
+            //in bottomtotop all is flipped
+            footer: Item {
+                height: heading.height
+                width: menu.width
+                Heading {
+                    id: heading
+                    anchors {
+                        left: parent.left
+                        right: parent.right
+                        margins: Units.largeSpacing
+                    }
+                    elide: Text.ElideRight
+                    level: 2
+                    text: root.title
+                }
+            }
+            delegate: ListItem {
+                enabled: true
+                Row {
+                    anchors {
+                        left: parent.left
+                        margins: Units.largeSpacing
+                    }
+                    Icon {
+                        height: parent.height
+                        width: height
+                        source: modelData.iconName
+                    }
+                    Label {
+                        text: model ? model.text : modelData.text
+                    }
+                }
+                onClicked: {
+                    if (modelData && modelData.trigger !== undefined) {
+                        modelData.trigger();
+                    // assume the model is a list of QAction or Action
+                    } else if (menu.model.length > index) {
+                        menu.model[index].trigger();
+                    } else {
+                        console.warning("Don't know how to trigger the action")
+                    }
+                }
+            }
+        }
+    }
+}