blob: ae6501a11a598b298f4876da07eb0ca4893318c6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:strip-space elements="*"/>
<xsl:output method="xml" indent="yes"/>
<xsl:include href="commonTemplates.xsl"/>
<xsl:template match="/">
<divelog program='subsurface-import' version='2'>
<dives>
<xsl:apply-templates select="/dive/diveLog"/>
</dives>
</divelog>
</xsl:template>
<xsl:template match="diveLog">
<xsl:variable name="units">
<xsl:choose>
<xsl:when test="imperialUnits = 'true'">
<xsl:value-of select="'imperial'"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="'metric'"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<dive>
<xsl:attribute name="number">
<xsl:value-of select="number"/>
</xsl:attribute>
<xsl:variable name="datetime">
<xsl:call-template name="convertDate">
<xsl:with-param name="dateTime">
<xsl:value-of select="startDate"/>
</xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:attribute name="date">
<xsl:value-of select="substring-before($datetime, ' ')"/>
</xsl:attribute>
<xsl:attribute name="time">
<xsl:value-of select="substring-after($datetime, ' ')"/>
</xsl:attribute>
<xsl:attribute name="duration">
<xsl:value-of select="concat(maxTime, ' min')"/>
</xsl:attribute>
<depth>
<xsl:attribute name="max">
<xsl:choose>
<xsl:when test="$units = 'imperial'">
<xsl:value-of select="maxDepth * 0.3048"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="maxDepth"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</depth>
<surface>
<xsl:attribute name="pressure">
<xsl:value-of select="concat(startSurfacePressure div 1000, ' bar')"/>
</xsl:attribute>
</surface>
<divecomputer>
<xsl:attribute name="model">
<xsl:value-of select="'Shearwater'"/>
</xsl:attribute>
<xsl:attribute name="deviceid">
<xsl:value-of select="computerSerial"/>
</xsl:attribute>
</divecomputer>
<xsl:for-each select="diveLogRecords/diveLogRecord">
<sample>
<xsl:attribute name="time">
<xsl:call-template name="sec2time">
<xsl:with-param name="timeSec">
<xsl:value-of select="currentTime"/>
</xsl:with-param>
</xsl:call-template>
</xsl:attribute>
<xsl:attribute name="depth">
<xsl:choose>
<xsl:when test="$units = 'imperial'">
<xsl:value-of select="format-number(currentDepth * 0.3048, '0.00')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="currentDepth"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:attribute name="temp">
<xsl:choose>
<xsl:when test="$units = 'imperial'">
<xsl:value-of select="concat(format-number((waterTemp - 32) * 5 div 9, '0.0'), ' C')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="waterTemp"/>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</sample>
</xsl:for-each>
</dive>
</xsl:template>
</xsl:stylesheet>
|
